少有人走的路单相机标定的目的是完成像素坐标到世界坐标之间在的转换。
使用halcon标定助手完成的即是单相机标定。
程序运行后，载入10张标定板文件，最后用calibrate_cameras算子执行标定。
这一步相当于标定向导中载入十标定板图片，最后点击标定按钮。
有关halcon标定向导的标定说明见勇哥的另一篇贴子《勇哥的视觉实验：halcon的标定助手》。
标定完成后，接下来进行测量。
先测量标定版外框之间的宽度，你可能注意到它的值是3.992cm，这个值明显不对。
因为照片中人托着标定板，少说也有半米宽是不是？
其实是因为代码中勇哥指定标定板的描述文件不对的原因。（它不是图片中那块巨大的标定板的描述文件）
CalTabDescrFile:='calib_40mmThick1.5.descr'
接下来显示标定板全部圆的半径1，半径2的平均值，以及这个平均值的标准差。
这个平均值与标准差分为图像坐标系和世界坐标系的两组值来显示。
代码如下：
dev_close_window()
dev_open_window(0, 0, 768, 576, 'black', WindowHandle)
dev_update_off()
dev_set_draw('margin')
dev_set_line_width(3)
set_display_font(WindowHandle, 14, 'mono', 'true', 'false')
*这里的标定板文件名要改成halcon安装目录下的calib目录下有的名字
*例如勇哥的安装目录是：E:\Program Files\MVTec\HALCON-18.11-Progress\calib
CalTabDescrFile:='calib_40mmThick1.5.descr'
gen_cam_par_area_scan_division (0.008, 0, 0.0000086, 0.0000086, 384, 288, 768, 576, StartCamPar)
create_calib_data ('calibration_object', 1, 1, CalibDataID)
set_calib_data_cam_param (CalibDataID, 0, [], StartCamPar)
set_calib_data_calib_object (CalibDataID, 0, CalTabDescrFile)
NumImages:=10
for I:=1 to NumImages by 1
read_image (Image, 'calib/calib-3d-coord-' + I$'02d')
dev_display (Image)
Message := 'Find calibration plate in\nall calibration images (' + I + '/' + NumImages + ')'
disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')
find_calib_object (Image, CalibDataID, 0, 0, I - 1, [], [])
get_calib_data(CalibDataID, 'camera', 0, 'init_params', StartCamPar)
*这里取得的外参Pose是预估值
get_calib_data_observ_points(CalibDataID, 0, 0, I-1, Row, Column, Index, Pose)
get_calib_data_observ_contours(Contours, CalibDataID, 'caltab', 0, 0, I-1)
gen_cross_contour_xld(Cross, Row, Column, 6, 0.785398)
dev_set_color('green')
dev_display(Contours)
dev_set_color('yellow')
dev_display(Cross)
endfor
disp_continue_message(WindowHandle, 'black','true')
stop()
*单相机标定
calibrate_cameras(CalibDataID, Error)
get_calib_data(CalibDataID, 'camera', 0, 'params', CamParam)
get_calib_data(CalibDataID, 'calib_obj_pose', [0,0], 'pose', Pose)
for I := 1 to NumImages by 1
read_image (Image, 'calib/calib-3d-coord-' + I$'02d')
*
* 现在测量标定片外黑边的宽度
get_measure_positions (Image, PlateRegion, CalibDataID, I, Distance, Phi, RowCenter, ColumnCenter)
gen_rectangle2_contour_xld (Rectangle, RowCenter, ColumnCenter, Phi, Distance * 0.52, 8)
gen_measure_rectangle2 (RowCenter, ColumnCenter, Phi, Distance * 0.52, 8, 768, 576, 'nearest_neighbor', MeasureHandle)
*
measure_pos (Image, MeasureHandle, 1, 40, 'all', 'all', RowEdge, ColumnEdge, Amplitude, Distance1)
Rows := [RowEdge[0],RowEdge[|RowEdge| - 1]]
Columns := [ColumnEdge[0],ColumnEdge[|RowEdge| - 1]]
gen_cross_contour_xld (Cross, Rows, Columns, 16, Phi)
*
* 两个边框上的点转为世界坐标
get_calib_data (CalibDataID, 'calib_obj_pose', [0,I - 1], 'pose', Pose)
image_points_to_world_plane (CamParam, Pose, Rows, Columns, 'm', SX, SY)
distance_pp (SY[0], SX[0], SY[1], SX[1], Width)
*
* 显示测量结果
dev_display (Image)
dev_set_color ('white')
dev_set_line_width (3)
dev_display (Rectangle)
dev_set_color ('green')
dev_set_draw ('fill')
dev_set_line_width (2)
dev_display (Cross)
dev_set_draw ('margin')
disp_message (WindowHandle, 'Width = ' + (Width * 100)$'8.3f' + 'cm', 'window', 12, 12, 'black', 'true')
disp_continue_message (WindowHandle, 'black', 'true')
*stop ()
wait_seconds(0.5)
*
* Now, measure the size of the calibration marks
*
* Extract the ellipses in the image
erosion_circle (PlateRegion, ROI, 17.5)
reduce_domain (Image, ROI, ImageReduced)
edges_sub_pix (ImageReduced, Edges, 'canny', 1, 20, 60)
select_contours_xld (Edges, SelectedEdges, 'contour_length', 20, 99999999, -0.5, 0.5)
* Fit ellipses to extracted edges
fit_ellipse_contour_xld (SelectedEdges, 'fitzgibbon', -1, 2, 0, 200, 3, 2, Row, Column, Phi, Radius1, Radius2, StartPhi, EndPhi, PointOrder)
MeanRadius1 := mean(Radius1)
MeanRadius2 := mean(Radius2)
DevRadius1 := deviation(Radius1)
DevRadius2 := deviation(Radius2)
* Transform the ellipses to world coordinates, where they should be circles
* and convert the circles from meters to millimeters so that we can see them.
contour_to_world_plane_xld (SelectedEdges, WorldCircles, CamParam, Pose, 'mm')
* Fit ellipses to the circles in world coordinates
fit_ellipse_contour_xld (WorldCircles, 'fitzgibbon', -1, 2, 0, 200, 3, 2, Row, Column, Phi, RadiusW1, RadiusW2, StartPhi, EndPhi, PointOrder)
MeanRadiusW1 := mean(RadiusW1)
MeanRadiusW2 := mean(RadiusW2)
DevRadiusW1 := deviation(RadiusW1)
DevRadiusW2 := deviation(RadiusW2)
*
* Display results of ellipse measurement
dev_display (Image)
dev_set_color ('yellow')
dev_set_line_width (3)
dev_display (SelectedEdges)
Message := 'Measured dimensions of the ellipses'
Message[0] := ' Mean Radius1; Mean Radius2; (Standard deviations [%])'
Message[1] := 'Image coordinates: ' + MeanRadius1$'5.2f' + 'px; ' + MeanRadius2$'5.2f' + 'px (' + (DevRadius1 / MeanRadius1 * 100)$'4.2f' + ', ' + (DevRadius2 / MeanRadius2 * 100)$'4.2f' + ')'
Message[2] := 'World coordinates: ' + (MeanRadiusW1 / 10)$'5.2f' + 'cm; ' + (MeanRadiusW2 / 10)$'5.2f' + 'cm (' + (DevRadiusW1 / MeanRadiusW1 * 100)$'4.2f' + ', ' + (DevRadiusW2 / MeanRadiusW2 * 100)$'4.2f' + ')'
disp_message (WindowHandle, Message, 'window', 12, 12, 'black', 'true')
if (I < 10)
disp_continue_message (WindowHandle, 'black', 'true')
stop ()
endif
wait_seconds(0.5)
endfor自定义函数get_measure_positions的代码如下：
* 提取特征 threshold (Image, Region, 0, 120) connection (Region, ConnectedRegions) select_shape (ConnectedRegions, SelectedRegions, ['holes_num','rect2_len1','rect2_len2'], 'and', [1,120,120], [1,200,200]) fill_up (SelectedRegions, PlateRegion) *从表的边框构造线条 gen_contour_region_xld (PlateRegion, Contours, 'center') //画轮廓 segment_contours_xld (Contours, ContoursSplit, 'lines', 7, 4, 2)//分割轮廓 regress_contours_xld (ContoursSplit, RegressContours, 'no', 1)//计算回归（后一步的先决条件,下一步包含direction or currature） select_contours_xld (RegressContours, VerticalContours, 'direction', rad(45), rad(135), -0.5, 0.5) //过滤轮廓 select_contours_xld (VerticalContours, LongContours, 'length', 150, 500, -0.5, 0.5) * 获取两条线段的端点 select_obj (LongContours, Contour, 1)//选第一条线 get_contour_xld (Contour, Rows, Columns) RowBegin1 := Rows[0] //两端点 ColBegin1 := Columns[0] RowEnd1 := Rows[|Rows| - 1] ColEnd1 := Columns[|Columns| - 1] select_obj (LongContours, Contour, 2)//第二条线 get_contour_xld (Contour, Rows, Columns) RowBegin2 := Rows[0] ColBegin2 := Columns[0] RowEnd2 := Rows[|Rows| - 1] ColEnd2 := Columns[|Columns| - 1] get_calib_data_observ_points (CalibDataID, 0, 0, PoseIndex - 1, Row, Column, PoseIndex, _Pose) //获取点坐标 Row1 := Row[find(PoseIndex,21)] //第22个和28个点 Row2 := Row[find(PoseIndex,27)] Column1 := Column[find(PoseIndex,21)] Column2 := Column[find(PoseIndex,27)] *找两个交点坐标 intersection_lines (Row1, Column1, Row2, Column2, RowBegin1, ColBegin1, RowEnd1, ColEnd1, RowA, ColA, IsOverlapping) //第一个交点 intersection_lines (Row1, Column1, Row2, Column2, RowBegin2, ColBegin2, RowEnd2, ColEnd2, RowB, ColB, IsOverlapping) //第二个交点 distance_pp (RowA, ColA, RowB, ColB, Distance) //距离 line_orientation (RowA, ColA, RowB, ColB, Phi) //角度 RowCenter := (RowA + RowB) / 2 //中心点 ColumnCenter := (ColA + ColB) / 2 return ()
这个函数的参数定义如下：
当载入标定板的描述文件后，相当于已知了世界坐系。7*7的圆点标定板又确定了图像坐标，知道了图像坐标与世界坐标就可以求出相机的内参与外参。
世界坐标系转像素坐标系的公式如下：
其中，红框处即世界坐标，相当于标定板描述文件的信息。
蓝框处即相机的内参，黄框处即相机的外参。
即图像坐标系。
这样，三样参数：相机内外参、图像坐标、世界坐标
已经任意两个，则可以求出第三个来。
上面的例程也就是说知道了世界坐标和图像坐标，求出相机内外参。
《本文源代码下载》
---------------------
作者：hackpig
来源：www.skcircle.com
版权声明：本文为博主原创文章，转载请附上博文链接！
本文出自勇哥的网站《少有人走的路》wwww.skcircle.com，转载请注明出处！讨论可扫码加群：
